Options are
indicated as A | B, meaning either A or B (but not
both). Parentheses specify scope. Elements within brackets are
optional. A+ indicates one or more occurrences of A,
A* indicates zero or more occurrences of A.
This section contains a specification of the grammar in BNF
(Backus-Naur Form). Terms in all capitals are reserved terms
(keywords). Lowercase terms are non-terminal. Terms with first letter
in capitals represent names or strings, that is, they are currently
``free text'' fields. Options are
indicated as A | B, meaning either A or B (but not
both). Parentheses specify scope. Elements within brackets are
optional. A+ indicates one or more occurrences of A,
A* indicates zero or more occurrences of A.
In order to help the visualization and understanding of this grammar (and considering that not everybody is well-acquainted with a BNF form), Figure 1 shows the main elements of the grammar as a part-of decomposition. Some elements are ommited or simplified for clarity.
[IMAGE ]
Figure 1: Main structure of the proposed
grammar for objectives. Arrows indicate types of fillers for one
element of the grammar.
Below is the BNF specification:
![[IMAGE ]](img1.gif){kind=link}
acp-objective ::= objective-type
Objective-name
action-specification
MEASURES OF MERIT measures-of-merit
PARENTS (Objective-name)+
[SEQUENCE RESTRICTIONS sequence-restrictions]
[COGS (COG-name)+]
[%COMPLETE Percentage]
[REVIEW STATUS review-status]
objective-type ::= CINC OBJECTIVE |
AIR OBJECTIVE |
AIR TASK |
AIR ACTIVITY |
AIR-MISSION
action-specification ::= text-action-spec |
structured-action-spec |
text-action-spec structured-action-spec
text-action-spec ::= TITLE Text-description
structured-action-spec ::= action-type
action-role+
[area-restriction]
[time-restriction]
action-type ::= Action-name
action-role ::= role-name role-object
role-name ::= Role | DOB
role-object ::= aspect |
object |
action |
action-capability |
area
aspect ::= (Object-qualification |
State)
[OF Owner/controller]
object ::= object-description
object-description ::= Object-type
[OF Owner/controller]
action ::= Action
[OF Owner/controller]
action-capability ::= Action-capability
[OF Owner/controller]
area-restriction ::= area-modifier area
area-modifier ::= OVER | IN | AT
area ::= Country |
Geographic-region |
conflict-side |
DESIRED CHOKEPOINTS AND RESTRICTED LOCS |
area AND area
conflict-side ::= GRAY | BLUE | RED
time-restriction ::= WITHIN time-period |
BEFORE time |
AFTER time |
BETWEEN time AND time
time ::= time-period | date
time-period ::= TIME-PERIOD Begin-time End-time
date ::= Date
measures-of-merit ::= Measure-of-merit [AND measures-of-merit]
sequence-restrictions ::= strength-modifier time-relation Objective-name+
[AND sequence-restrictions]
strength-modifier ::= MUST |
SHOULD |
SHOULD NOT |
MUST NOT
time-relation ::= BEFORE |
AFTER |
SIMULTANEOUS WITH
review-status ::= DEFAULT | REVIEWED | CHANGED
The typologies for these elements must be defined in detail within an ARPI-wide effort towards a shared ontology. When such typologies are defined, it will be possible to define a set of fillers (or a more specific grammar) for these items.
Independently of these efforts, a more specific grammar will be developed shortly for the elements: Aspect, State and Time-period, because in the development process these seem to require further structuring.
The following are examples of how some objectives can be represented in the proposed grammar. They are adapted (substituting country names) from actual objectives used in IFD-4. The quotes in some elements are not necessary, and are used for clarity, to emphasize groups of words that are playing the same grammatical role. Primitive terms of the grammar are indicated by capital letters. The DOB token is ommitted for clarity. Some COGs and sequence restrictions were added for illustration purposes.
AIR OBJECTIVE O1
Maintain "air superiority" OF BLUE OVER "Friendly forces"
MEASURES OF MERIT
"No loss of Allied Aircraft to enemy surface or air forces"
AND
"No enemy aircraft deliver weapons against allied forces"
PARENTS C1
SEQUENCE-RESTRICTIONS SHOULD BEFORE O2 O3
COGS COG1 COG2
AIR-OBJECTIVE O2
Disrupt "military control" OF "population" OF "Enemy"
MEASURES-OF-MERIT
"Reduce communication effectiveness by 50%"
AND
"Force use of More vulnerable Transmission Systems"
PARENTS C2 C4
SEQUENCE-RESTRICTIONS SHOULD BEFORE O3
COGS COG2
AIR-TASK T1
Maintain "Air Supremacy" OVER "battlefield and engaged waters"
MEASURES-OF-MERIT
"Freedom of air movement over the battlespace"
AND
"No losses of friendly air forces to SAMS/AAA/Aircraft over the battlespace"
PARENTS O1
SEQUENCE-RESTRICTIONS MUST BEFORE T2
COGS COG2
AIR-TASK T2
Destroy "Naval activity" of "Red" IN "Eastern Sea"
MEASURES-OF-MERIT
"No engagement of Allied forces by enemy naval vessels"
AND
"No reduction of Friendly shipping due to Enemy naval vessels''
PARENTS O1 O5
COGS COG2